1. 准备工作

选择一个目标磁盘分区，例如 D: 盘，并在该分区下创建一个用于安装 Ollama 的文件夹，例如 D:\ollama。

2. 下载 Ollama

访问 Ollama 的官网下载 https://ollama.com/download

3. 安装

运行OllamaSetup.exe进行安装

4. 验证安装

ollama --version

5.复制文件

在目标磁盘新建Ollama目录假设为D盘，将以下目录复制到新建的目录

C:\Users\Windows用户名\.ollama                           D:\Ollama\.ollama
C:\Users\Windows用户名\AppData\Local\Ollama              D:\Ollama\log
C:\Users\Windows用户名\AppData\Local\Programs\Ollama     D:\Ollama\app

6、删除旧文件夹

删除原来C盘三个路径的旧目录

7、创建符号链接

mklink /D C:\Users\Windows用户名\.ollama D:\Ollama\.ollama
mklink /D C:\Users\Windows用户名\AppData\Local\Ollama D:\Ollama\log
mklink /D C:\Users\Windows用户名\AppData\Local\Programs\Ollama D:\Ollama\app

8、添加环境变量

     按下 Win + R 组合键，输入 sysdm.cpl 并回车，打开 “系统属性” 窗口。

     在 “系统属性” 窗口中，点击 “高级” 选项卡，然后点击 “环境变量” 按钮。

     添加以下环境变量

PATH D:\Ollama\app
OLLAMA_HOST 0.0.0.0
OLLAMA_MODELS D:\Ollama\.ollama\models

9、验证结果

CMD执行Ollama

C:\Users\Administrator>Ollama list
NAME                                    ID              SIZE      MODIFIED
deepseek-coder-v2:latest                63fb193b3a9b    8.9 GB    13 minutes ago
huihui_ai/qwen2.5-abliterate:latest     103482475c9b    4.7 GB    About an hour ago
huihui_ai/deepseek-r1-abliterated:7b    9e25a373f069    4.7 GB    About an hour ago
deepseek-r1:7b                          0a8c26691023    4.7 GB    About an hour ago

附录 一键操作批处理如下：

@echo off
rem 确保以管理员权限运行
net session >nul 2>&1
if %errorLevel% neq 0 (
    echo 此脚本需要以管理员权限运行，请右键选择“以管理员身份运行”。
    pause
    exit /b 1
)

rem 定义原目录，使用系统环境变量
set "sourceDir1=%USERPROFILE%\.ollama"
set "sourceDir2=%USERPROFILE%\AppData\Local\Ollama"
set "sourceDir3=%USERPROFILE%\AppData\Local\Programs\Ollama"

rem 提示用户输入目标盘符
set /p targetDrive=请输入目标盘符（例如：I:）：

rem 定义新目录
set "targetDir1=%targetDrive%\Ollama\.ollama"
set "targetDir2=%targetDrive%\Ollama\log"
set "targetDir3=%targetDrive%\Ollama\app"

rem 创建目标目录（如果不存在）
if not exist "%targetDir1%" mkdir "%targetDir1%"
if not exist "%targetDir2%" mkdir "%targetDir2%"
if not exist "%targetDir3%" mkdir "%targetDir3%"

rem 拷贝原目录文件和文件夹到新目录
xcopy /E /I /Y /H "%sourceDir1%\*" "%targetDir1%\"
xcopy /E /I /Y /H "%sourceDir2%\*" "%targetDir2%\"
xcopy /E /I /Y /H "%sourceDir3%\*" "%targetDir3%\"

rem 删除原有的目录
rmdir /s /q "%sourceDir1%" 2>nul
rmdir /s /q "%sourceDir2%" 2>nul
rmdir /s /q "%sourceDir3%" 2>nul

rem 创建符号链接
mklink /D "%sourceDir1%" "%targetDir1%"
mklink /D "%sourceDir2%" "%targetDir2%"
mklink /D "%sourceDir3%" "%targetDir3%"

rem 将新的app目录添加到系统环境变量PATH中
setx PATH "%PATH%;%targetDir3%" /M

rem 添加OLLAMA_HOST环境变量
setx OLLAMA_HOST "0.0.0.0" /M

rem 添加OLLAMA_MODELS环境变量，使用之前定义的环境变量来定义路径
setx OLLAMA_MODELS "%targetDir1%\models" /M

echo 操作完成。
pause